Add support for extra rustc environment variables

This adds support for injecting environment variables into rustc invocations
via build settings:

- `//rust/settings:extra_rustc_env` for the target configuration
- `//rust/settings:extra_exec_rustc_env` for the exec configuration

These settings can be set from the command line with flags like:

```
  --@rules_rust//rust/settings:extra_rustc_env=RUSTC_BOOTSTRAP=1
```

This mirrors how extra rustc flags are handled and enables build-wide env-based
feature control without editing individual rules. Useful for enabling unstable
features across many crates, or toggling behavior in proc macros and build scripts.

Author: nmattia

rust/private/rust.bzl

@@ -543,12 +543,18 @@ RUSTC_ATTRS = {
     "_extra_exec_rustc_flags": attr.label(
         default = Label("//rust/settings:extra_exec_rustc_flags"),
     ),
+    "_extra_exec_rustc_env": attr.label(
+        default = Label("//rust/settings:extra_exec_rustc_env"),
+    ),
     "_extra_rustc_flag": attr.label(
         default = Label("//rust/settings:extra_rustc_flag"),
     ),
     "_extra_rustc_flags": attr.label(
         default = Label("//rust/settings:extra_rustc_flags"),
     ),
+    "_extra_rustc_env": attr.label(
+        default = Label("//rust/settings:extra_rustc_env"),
+    ),
     "_is_proc_macro_dep": attr.label(
         default = Label("//rust/private:is_proc_macro_dep"),
     ),

rust/private/rustc.bzl

@@ -77,6 +77,16 @@ ExtraExecRustcFlagsInfo = provider(
     fields = {"extra_exec_rustc_flags": "List[string] Extra flags to pass to rustc in exec configuration"},
 )
 
+ExtraRustcEnvInfo = provider(
+    doc = "Pass each value as an environment variable to non-exec rustc invocations",
+    fields = {"extra_rustc_env": "List[string] Extra env to pass to rustc in non-exec configuration"},
+)
+
+ExtraExecRustcEnvInfo = provider(
+    doc = "Pass each value as an environment variable to exec rustc invocations",
+    fields = {"extra_exec_rustc_env": "List[string] Extra env to pass to rustc in exec configuration"},
+)
+
 PerCrateRustcFlagsInfo = provider(
     doc = "Pass each value as an additional flag to non-exec rustc invocations for crates matching the provided filter",
     fields = {"per_crate_rustc_flags": "List[string] Extra flags to pass to rustc in non-exec configuration"},
@@ -1111,6 +1121,9 @@ def construct_arguments(
     if hasattr(ctx.attr, "_extra_rustc_flag") and not is_exec_configuration(ctx):
         rustc_flags.add_all(ctx.attr._extra_rustc_flag[ExtraRustcFlagsInfo].extra_rustc_flags, map_each = map_flag)
 
+    if hasattr(ctx.attr, "_extra_rustc_env") and not is_exec_configuration(ctx):
+        env.update(ctx.attr._extra_rustc_env[ExtraRustcEnvInfo].extra_rustc_env)
+
     if hasattr(ctx.attr, "_per_crate_rustc_flag") and not is_exec_configuration(ctx):
         per_crate_rustc_flags = ctx.attr._per_crate_rustc_flag[PerCrateRustcFlagsInfo].per_crate_rustc_flags
         _add_per_crate_rustc_flags(ctx, rustc_flags, map_flag, crate_info, per_crate_rustc_flags)
@@ -1121,6 +1134,9 @@ def construct_arguments(
     if hasattr(ctx.attr, "_extra_exec_rustc_flag") and is_exec_configuration(ctx):
         rustc_flags.add_all(ctx.attr._extra_exec_rustc_flag[ExtraExecRustcFlagsInfo].extra_exec_rustc_flags, map_each = map_flag)
 
+    if hasattr(ctx.attr, "_extra_exec_rustc_env") and is_exec_configuration(ctx):
+        env.update(ctx.attr._extra_exec_rustc_env[ExtraExecRustcEnvInfo].extra_exec_rustc_env)
+
     if _is_no_std(ctx, toolchain, crate_info):
         rustc_flags.add('--cfg=feature="no_std"')
 
@@ -2353,6 +2369,42 @@ extra_rustc_flag = rule(
     build_setting = config.string_list(flag = True, repeatable = True),
 )
 
+def _extra_rustc_env_impl(ctx):
+    env_vars = {}
+    for entry in ctx.build_setting_value:
+        if "=" not in entry:
+            fail("Invalid format for rustc env var: '{}'. Expected 'KEY=value'".format(entry))
+        key, val = entry.split("=", 1)
+        env_vars[key] = val
+    return ExtraRustcEnvInfo(extra_rustc_env = env_vars)
+
+extra_rustc_env = rule(
+    doc = (
+        "Add additional environment variables to rustc in non-exec configuration using " +
+        "`--@rules_rust//rust/settings:extra_rustc_env=FOO=bar`. Multiple values may be specified."
+    ),
+    implementation = _extra_rustc_env_impl,
+    build_setting = config.string_list(flag = True),
+)
+
+def _extra_exec_rustc_env_impl(ctx):
+    env_vars = {}
+    for entry in ctx.build_setting_value:
+        if "=" not in entry:
+            fail("Invalid format for rustc env var: '{}'. Expected 'KEY=value'".format(entry))
+        key, val = entry.split("=", 1)
+        env_vars[key] = val
+    return ExtraExecRustcEnvInfo(extra_exec_rustc_env = env_vars)
+
+extra_exec_rustc_env = rule(
+    doc = (
+        "Add additional environment variables to rustc in non-exec configuration using " +
+        "`--@rules_rust//rust/settings:extra_exec_rustc_env=FOO=bar`. Multiple values may be specified."
+    ),
+    implementation = _extra_exec_rustc_env_impl,
+    build_setting = config.string_list(flag = True),
+)
+
 def _extra_exec_rustc_flags_impl(ctx):
     return ExtraExecRustcFlagsInfo(extra_exec_rustc_flags = ctx.build_setting_value)
 

rust/settings/BUILD.bazel

@@ -17,8 +17,10 @@ load(
     "experimental_use_sh_toolchain_for_bootstrap_process_wrapper",
     "extra_exec_rustc_flag",
     "extra_exec_rustc_flags",
+    "extra_exec_rustc_env",
     "extra_rustc_flag",
     "extra_rustc_flags",
+    "extra_rustc_env",
     "incompatible_change_clippy_error_format",
     "incompatible_change_rust_test_compilation_output_directory",
     "incompatible_do_not_include_data_in_compile_data",
@@ -86,10 +88,14 @@ extra_exec_rustc_flag()
 
 extra_exec_rustc_flags()
 
+extra_exec_rustc_env()
+
 extra_rustc_flag()
 
 extra_rustc_flags()
 
+extra_rustc_env()
+
 incompatible_change_clippy_error_format()
 
 incompatible_change_rust_test_compilation_output_directory()

rust/settings/settings.bzl

@@ -21,8 +21,10 @@ load(
     _error_format = "error_format",
     _extra_exec_rustc_flag = "extra_exec_rustc_flag",
     _extra_exec_rustc_flags = "extra_exec_rustc_flags",
+    _extra_exec_rustc_env = "extra_exec_rustc_env",
     _extra_rustc_flag = "extra_rustc_flag",
     _extra_rustc_flags = "extra_rustc_flags",
+    _extra_rustc_env = "extra_rustc_env",
     _no_std = "no_std",
     _per_crate_rustc_flag = "per_crate_rustc_flag",
     _rustc_output_diagnostics = "rustc_output_diagnostics",
@@ -399,6 +401,30 @@ def extra_exec_rustc_flag():
         build_setting_default = [],
     )
 
+# buildifier: disable=unnamed-macro
+def extra_rustc_env():
+    """This setting may be used to pass extra environment variables to rustc from the command line in non-exec configuration.
+
+    It applies across all targets whereas environment variables set in a specific rule apply only to that target.
+    This can be useful for setting build-wide env flags such as `RUSTC_BOOTSTRAP=1`.
+    """
+    _extra_rustc_env(
+        name = "extra_rustc_env",
+        build_setting_default = [],
+    )
+
+# buildifier: disable=unnamed-macro
+def extra_exec_rustc_env():
+    """This setting may be used to pass extra environment variables to rustc from the command line in exec configuration.
+
+    It applies to tools built and run during the build process, such as proc-macros and build scripts.
+    This can be useful for enabling features that are needed during tool compilation.
+    """
+    _extra_exec_rustc_env(
+        name = "extra_exec_rustc_env",
+        build_setting_default = [],
+    )
+
 # buildifier: disable=unnamed-macro
 def experimental_per_crate_rustc_flag():
     """Add additional rustc_flag to matching crates from the command line with `--@rules_rust//rust/settings:experimental_per_crate_rustc_flag`.