Follow Windows argument quoting rules

Fixes #142

Author: nmisch

lib/IPC/Run/Win32Helper.pm

@@ -323,6 +323,11 @@ trying to be a little cross-platform here.  The only difference is
 that "\" is *not* treated as an escape except when it precedes 
 punctuation, since it's used all over the place in DOS path specs.
 
+TODO: strip caret escapes?
+
+TODO: use
+https://docs.microsoft.com/en-us/cpp/cpp/main-function-command-line-args#parsing-c-command-line-arguments
+
 TODO: globbing? probably not (it's unDOSish).
 
 TODO: shebang emulation? Probably, but perhaps that should be part
@@ -396,6 +401,26 @@ sub _dup2_gently {
     IPC::Run::_dup2_rudely( $fd1, $fd2 );
 }
 
+# Quote a string for use in the lpCommandLine argument of CreateProcessA(), such
+# that the string yields a single argv element in the callee.
+# https://docs.microsoft.com/en-us/cpp/cpp/main-function-command-line-args#parsing-c-command-line-arguments
+# gives the algorithm for translating a command line to an argv.
+sub _quote_cmd_line_arg {
+    my $arg = shift;
+
+    # Skip optional quoting.
+    return $arg unless $arg =~ /[\"\s]|^$/;
+
+    # Change N >= 0 backslashes before a double quote to 2N+1 backslashes.
+    $arg =~ s/(\\*)"/${\($1 . $1)}\\"/gs;
+
+    # Change N >= 1 backslashes at end of argument to 2N backslashes.
+    $arg =~ s/(\\+)\z/${\($1 . $1)}/gs;
+
+    # Wrap the whole thing in unescaped double quotes.
+    return "\"$arg\"";
+}
+
 sub win32_spawn {
     my ( $cmd, $ops ) = @_;
 
@@ -442,11 +467,7 @@ sub win32_spawn {
     }
 
     my $process;
-    my $cmd_line = join " ", map {
-        ( my $s = $_ ) =~ s/"/"""/g;
-        $s = qq{"$s"} if /[\"\s]|^$/;
-        $s;
-    } @$cmd;
+    my $cmd_line = join " ", map { _quote_cmd_line_arg $_ } @$cmd;
 
     _debug "cmd line: ", $cmd_line
       if _debugging;

t/run.t

@@ -38,7 +38,7 @@ sub get_warnings {
 select STDERR;
 select STDOUT;
 
-use Test::More tests => 268;
+use Test::More tests => 271;
 use IPC::Run::Debug qw( _map_fds );
 use IPC::Run qw( :filters :filter_imp start );
 
@@ -210,6 +210,21 @@ is $? >> 8, 42;
 is( _map_fds, $fd_map );
 $fd_map = _map_fds;
 
+##
+## Arguments bearing all permitted bytes and special sequences of bytes
+##
+my $ascii;
+for my $i ( 1 .. 127 ) {
+
+    # skip BEL, since it's noisy and not otherwise special
+    $ascii .= sprintf( '%c', $i ) unless $i == 7;
+}
+my $bs_dquote_bs = qq{\\"\\az\\\\"\\\\\\};
+foreach my $payload ( $ascii, $bs_dquote_bs, "$bs_dquote_bs\n" ) {
+    $r = run [ $perl, '-e', 'print @ARGV', $payload ], '>', \$out;
+    eok( $out, $payload );
+}
+
 ##
 ## A function
 ##