Merge pull request #56 from nanto/date-format-timezone

Format DateTime with non-UTC time zone correctly

Author: davorg

lib/XML/Feed/Util.pm

@@ -19,10 +19,12 @@ our @EXPORT_OK = qw(
 );
 
 sub format_w3cdtf {
-    my $date = DateTime::Format::W3CDTF->format_datetime(shift);
+    my $dt = shift;
+
+    my $date = DateTime::Format::W3CDTF->format_datetime($dt);
 
     # Add timezone "Z" if "floating" DateTime.
-    $date =~ s/(:\d\d(?:\.\d+)?)\s*$/$1Z/;
+    $date .= 'Z' if $dt->time_zone->is_floating;
 
     return $date;
 }

t/30-date-format-timezone.t

@@ -0,0 +1,40 @@
+use strict;
+use warnings;
+use Test::More;
+
+use DateTime;
+use XML::XPath;
+
+use XML::Feed;
+use XML::Feed::Entry;
+
+# https://github.com/davorg/xml-feed/issues/55
+
+my $feed = XML::Feed->new('Atom');
+
+# Bugs are with DateTime with non-UTC time zone.
+my $dt = DateTime->now(time_zone => 'Asia/Tokyo');
+
+$feed->title("My Atom feed");
+$feed->link("http://www.example.com");
+$feed->author("Author");
+$feed->updated($dt);
+$feed->id("urn:uuid:1225c695-cfb8-4ebb-aaaa-80da344eaa6a");
+
+my $entry = XML::Feed::Entry->new('Atom');
+$entry->title("An important event");
+$entry->author("Important author");
+$entry->content("A very interesting event happened.");
+
+$entry->issued($dt);
+$entry->updated($dt);
+$entry->id("urn:uuid:1225c695-cfb8-4ebb-aaaa-80da344efa6a");
+
+$feed->add_entry($entry);
+
+my $xp = XML::XPath->new(xml => $feed->as_xml);
+my $rfc3339 = qr!<updated>\d{4}-\d{2}-\d{2}T.+\+09:00</updated>!;
+like $xp->findnodes_as_string('/feed/updated'), $rfc3339;
+like $xp->findnodes_as_string('/feed/entry/updated'), $rfc3339;
+
+done_testing();