Fix race to load NIF

This happens when multiple processes call GPIO.open at the same time.
NIFs can only be loaded once only one process gets an `:ok` return. The
others get an error telling them not to do that. That's harmless so just
try calling the function again.

The included unit test starts 32 processes in a race to open the GPIO.
On my MBP, a whole bunch of the processes would get the reload error
before the fix.

Fixes #178

Author: fhunleth

lib/gpio/gpio_nif.ex

@@ -5,16 +5,19 @@
 defmodule Circuits.GPIO.Nif do
   @moduledoc false
 
-  defp load_nif() do
+  defp load_nif_and_apply(fun, args) do
     nif_binary = Application.app_dir(:circuits_gpio, "priv/gpio_nif")
 
-    :erlang.load_nif(to_charlist(nif_binary), 0)
+    # Optimistically load the NIF. Handle the possible race.
+    case :erlang.load_nif(to_charlist(nif_binary), 0) do
+      :ok -> apply(__MODULE__, fun, args)
+      {:error, {:reload, _}} -> apply(__MODULE__, fun, args)
+      error -> error
+    end
   end
 
   def open(pin_number, pin_direction, initial_value, pull_mode) do
-    with :ok <- load_nif() do
-      apply(__MODULE__, :open, [pin_number, pin_direction, initial_value, pull_mode])
-    end
+    load_nif_and_apply(:open, [pin_number, pin_direction, initial_value, pull_mode])
   end
 
   def close(_gpio) do
@@ -46,7 +49,6 @@ defmodule Circuits.GPIO.Nif do
   end
 
   def info() do
-    :ok = load_nif()
-    apply(__MODULE__, :info, [])
+    load_nif_and_apply(:info, [])
   end
 end

test/circuits_gpio_test.exs

@@ -272,4 +272,21 @@ defmodule Circuits.GPIOTest do
       assert false == :code.purge(Circuits.GPIO)
     end
   end
+
+  test "racing to load the NIF" do
+    # Make sure the NIF isn't loaded
+    assert true == :code.delete(Circuits.GPIO.Nif)
+    assert false == :code.purge(Circuits.GPIO.Nif)
+
+    # Try to hit the race by having 32 processes race to load the NIF
+    tasks =
+      for index <- 0..31 do
+        Task.async(fn ->
+          {:ok, gpio} = GPIO.open(index, :input)
+          GPIO.close(gpio)
+        end)
+      end
+
+    Enum.each(tasks, &Task.await/1)
+  end
 end