harmonize tests with h5fortran. add rank check on read

Author: scivision

src/CMakeLists.txt

@@ -7,12 +7,22 @@ endif()
 configure_file(pathlib.in.f90 pathlib.f90)
 
 set(reader_template "
-integer :: varid, ier
+integer :: varid, ier, drank
+
 
 if(.not.self%is_open) error stop 'ERROR:nc4fortran:reader file handle not open'
 
 ier = nf90_inq_varid(self%ncid, dname, varid)
 
+if(ier == NF90_NOERR) then
+  ier = nf90_inquire_variable(self%ncid, varid, ndims=drank)
+  if(drank /= rank(value)) then
+    ier = NF90_EDIMSIZE
+    write(stderr,*) 'ERROR: ' // dname // ' rank ', drank, ' /= variable rank ',rank(value)
+    return
+  endif
+endif
+
 if(ier == NF90_NOERR) then
 select type (value)
 type is (real(real64))

src/interface.f90

@@ -5,7 +5,7 @@ module nc4fortran
 
 use netcdf, only : nf90_create, nf90_open, NF90_WRITE, NF90_CLOBBER, NF90_NETCDF4, NF90_MAX_NAME, &
   NF90_NOERR, NF90_EHDFERR, NF90_EBADNAME, NF90_EBADDIM, NF90_EBADTYPE, NF90_EBADGRPID, NF90_ENOTNC, NF90_ENOTVAR, &
-  NF90_ECHAR, NF90_EEDGE, NF90_ENAMEINUSE, NF90_EBADID, NF90_EINDEFINE, NF90_NOWRITE, &
+  NF90_ECHAR, NF90_EEDGE, NF90_ENAMEINUSE, NF90_EBADID, NF90_EINDEFINE, NF90_NOWRITE, NF90_EDIMSIZE, &
   nf90_open, nf90_close, nf90_estride, nf90_inq_varid, nf90_inq_dimid, nf90_inquire_dimension, &
   nf90_def_dim, nf90_def_var, nf90_get_var, nf90_put_var, &
   nf90_inq_libvers, nf90_sync
@@ -391,6 +391,8 @@ logical function check_error(code, dname)
   m = 'ERROR: ' // dname // ' Name contains illegal characters.'
 case (NF90_EBADTYPE)
   m = 'ERROR: ' // dname // ' specified type is not a valid netCDF type'
+case (NF90_EDIMSIZE)
+  m = 'ERROR: ' // dname // ' bad dimension size'
 case (NF90_EBADDIM)
   m = 'ERROR: ' // dname // ' invalid dimension ID or Name'
 case (NF90_EBADGRPID)

src/tests/CMakeLists.txt

@@ -1,31 +1,40 @@
-set(tmpdir ${CMAKE_CURRENT_BINARY_DIR})
-
-add_executable(test_io test_io.f90)
-target_link_libraries(test_io nc4fortran::nc4fortran)
+add_executable(test_array test_array.f90)
+target_link_libraries(test_array nc4fortran::nc4fortran)
 if(CMAKE_Fortran_COMPILER_ID STREQUAL GNU)
-  target_compile_options(test_io PRIVATE -Wno-compare-reals)
+  target_compile_options(test_array PRIVATE -Wno-compare-reals)
 endif()
-add_test(NAME nc4fortran:readwrite COMMAND $<TARGET_FILE:test_io> ${CMAKE_CURRENT_BINARY_DIR})
+add_test(NAME nc4fortran:array COMMAND $<TARGET_FILE:test_array>
+  WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
 
-add_executable(test_attr test_attr.f90)
-target_link_libraries(test_attr nc4fortran::nc4fortran)
-add_test(NAME nc4fortran:attributes COMMAND $<TARGET_FILE:test_attr> ${CMAKE_CURRENT_BINARY_DIR})
+add_executable(test_attributes test_attributes.f90)
+target_link_libraries(test_attributes nc4fortran::nc4fortran)
 if(${CMAKE_Fortran_COMPILER_ID} STREQUAL GNU)
-  target_compile_options(test_attr PRIVATE -Wno-compare-reals)
+  target_compile_options(test_attributes PRIVATE -Wno-compare-reals)
 endif()
+add_test(NAME nc4fortran:attributes COMMAND $<TARGET_FILE:test_attributes>
+  WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
 
-add_executable(test_errors test_errors.f90)
-target_link_libraries(test_errors nc4fortran::nc4fortran)
-add_test(NAME nc4fortran:errors COMMAND $<TARGET_FILE:test_errors> ${CMAKE_CURRENT_BINARY_DIR})
+add_executable(test_error test_error.f90)
+target_link_libraries(test_error nc4fortran::nc4fortran)
+add_test(NAME nc4fortran:error COMMAND $<TARGET_FILE:test_error>
+ WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
 
 add_executable(test_exist test_exist.f90)
 target_link_libraries(test_exist PRIVATE nc4fortran::nc4fortran)
-add_test(NAME nc4fortran:test_exist COMMAND $<TARGET_FILE:test_exist> ${tmpdir})
+add_test(NAME nc4fortran:test_exist COMMAND $<TARGET_FILE:test_exist>
+  WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
+
+add_executable(test_scalar test_scalar.f90)
+target_link_libraries(test_scalar PRIVATE nc4fortran::nc4fortran)
+add_test(NAME nc4fortran:test_scalar COMMAND $<TARGET_FILE:test_scalar>
+  WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
 
 add_executable(test_string test_string.f90)
 target_link_libraries(test_string nc4fortran::nc4fortran)
-add_test(NAME nc4fortran:test_string COMMAND $<TARGET_FILE:test_string> ${tmpdir})
+add_test(NAME nc4fortran:test_string COMMAND $<TARGET_FILE:test_string>
+  WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
 
 add_executable(test_shape test_shape.f90)
 target_link_libraries(test_shape PRIVATE nc4fortran::nc4fortran)
-add_test(NAME nc4fortran:shape_check COMMAND $<TARGET_FILE:test_shape> ${tmpdir})
+add_test(NAME nc4fortran:shape_check COMMAND $<TARGET_FILE:test_shape>
+  WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})

src/tests/meson.build

@@ -3,15 +3,15 @@ test_io = executable('test_io', 'test_io.f90',
   dependencies: netcdf_interface)
 test('ReadWrite', test_io,  args: meson.current_build_dir(), timeout: 10, suite: 'nc4basic')
 
-test_attr = executable('test_attr', 'test_attr.f90',
+test_attr = executable('test_attributes', 'test_attributes.f90',
   fortran_args: quiet,
   dependencies: netcdf_interface)
 test('attributes', test_attr, args: meson.current_build_dir(), timeout: 10, suite: 'nc4basic')
 
-test_errors = executable('test_errors', 'test_errors.f90',
+test_error = executable('test_error', 'test_error.f90',
   fortran_args: quiet,
   dependencies: netcdf_interface)
-test('errors', test_errors, args: meson.current_build_dir(), timeout: 10, suite: 'nc4basic')
+test('errors', test_error, args: meson.current_build_dir(), timeout: 10, suite: 'nc4basic')
 
 test_exist = executable('test_exist', 'test_exist.f90',
   fortran_args: quiet,

src/tests/test_array.f90

@@ -0,0 +1,104 @@
+program array_test
+
+use, intrinsic:: iso_fortran_env, only: int64, int32, real32, real64, stderr=>error_unit
+use, intrinsic:: ieee_arithmetic, only: ieee_value, ieee_quiet_nan, ieee_is_nan
+use nc4fortran, only : netcdf_file
+
+implicit none (type, external)
+
+real(real32) :: nan
+
+call test_basic_array()
+print *,'PASSED: array write'
+
+contains
+
+subroutine test_basic_array()
+
+type(netcdf_file) :: h
+integer, allocatable :: dims(:)
+character(*), parameter :: filename = 'test_array.nc'
+
+integer(int32), dimension(4) :: i1, i1t
+integer(int32), dimension(4,4) :: i2, i2t
+integer(int64), dimension(4,4) :: i2t64
+real(real32), allocatable :: rr2(:,:)
+real(real32)  ::  nant, r1(4), r2(4,4), B(6,6)
+integer :: i, ierr
+integer(int32) :: i2_8(8,8)
+
+nan = ieee_value(1.0, ieee_quiet_nan)
+
+do i = 1,size(i1)
+  i1(i) = i
+enddo
+
+i2(1,:) = i1
+do i = 1,size(i2,2)
+  i2(i,:) = i2(1,:) * i
+enddo
+
+r1 = i1
+r2 = i2
+
+call h%initialize(filename, status='replace', comp_lvl=1)
+
+call h%write('int32-1d', i1)
+call h%write('int32-2d', i2, ['x', 'y'])
+call h%write('int64-2d', int(i2, int64))
+call h%write('real32-2d', r2)
+call h%write('nan', nan)
+
+!> test writing wrong size
+call h%write('int32-1d', [-1], ierr=ierr)
+if(ierr==0) error stop 'test_write_array: did not error for write array shape mismatch'
+
+!> test writing wrong rank
+call h%write('int32-1d', i2, ierr=ierr)
+if(ierr==0) error stop 'test_write_array: did not error for write array rank mismatch'
+
+call h%finalize()
+
+!! read
+call h%initialize(filename, status='old', action='r')
+
+!> int32
+call h%read('int32-1d', i1t)
+if (.not.all(i1==i1t)) error stop 'read 1-d int32: does not match write'
+
+call h%read('int32-2d',i2t)
+if (.not.all(i2==i2t)) error stop 'read 2-D: int32 does not match write'
+
+call h%read('int64-2d',i2t64)
+if (.not.all(i2==i2t64)) error stop 'read 2-D: int64 does not match write'
+
+!> verify reading into larger array
+i2_8 = 0
+call h%read('int32-2d', i2_8(2:5,3:6))
+if (.not.all(i2_8(2:5,3:6) == i2)) error stop 'read into larger array fail'
+
+!> check error for reading array dimension mismatch
+
+!> check that 1D disk into 2D raises error
+call h%read('int32-1d', i2, ierr)
+if (ierr==0) error stop 'failed to error on read rank mismatch'
+
+!> real
+call h%shape('real32-2d',dims)
+allocate(rr2(dims(1), dims(2)))
+call h%read('real32-2d',rr2)
+if (.not.all(r2 == rr2)) error stop 'real 2-D: read does not match write'
+print *,'read large'
+! check read into a variable slice
+call h%read('real32-2d', B(2:5,3:6))
+if(.not.all(B(2:5,3:6) == r2)) error stop 'real 2D: reading into variable slice'
+
+call h%read('nan',nant)
+if (.not.ieee_is_nan(nant)) error stop 'failed storing or reading NaN'
+
+call h%finalize()
+
+end subroutine test_basic_array
+
+
+end program

src/tests/test_attr.f90 renamed to src/tests/test_attributes.f90

@@ -5,16 +5,7 @@ program test_attr
 
 implicit none (type, external)
 
-character(:), allocatable :: path, filename
-character(1024) :: argv
-
-
-if(command_argument_count() /= 1) error stop 'input temp path'
-call get_command_argument(1, argv)
-path = trim(argv)
-
-filename = path // '/test_attr.nc'
-
+character(*), parameter :: filename = 'test_attr.h5'
 
 call test_write_attributes(filename)
 print *,'PASSED: write attributes'
@@ -76,5 +67,4 @@ subroutine test_read_attributes(path)
 
 end subroutine test_read_attributes
 
-
 end program

src/tests/test_error.f90

@@ -0,0 +1,113 @@
+program test_errors
+use, intrinsic:: iso_fortran_env, only: int64, int32, real32, real64, stderr=>error_unit
+use nc4fortran, only: netcdf_file, NF90_NOERR
+
+implicit none (type, external)
+
+call test_nonexist_old_file()
+print *, 'OK: non-existing old file'
+call test_nonexist_unknown_file()
+print *, 'OK: non-existing unknown file'
+call test_nonnetcdf_file()
+print *, 'OK: non-NetCDF file'
+call test_nonexist_variable()
+print *, 'OK: non-existing variable'
+call test_wrong_type()
+print *, "OK: wrong type read"
+call test_unknown_write()
+print *, 'OK: unknown write'
+call test_unknown_read()
+print *, 'OK: unknown read'
+
+contains
+
+
+subroutine test_nonexist_old_file()
+integer :: ierr
+type(netcdf_file) :: h
+
+call h%initialize('not-exist.nc', ierr, status='old', action='read')
+if (ierr==NF90_NOERR) error stop 'should have had ierr/=0 on non-existing old file'
+end subroutine test_nonexist_old_file
+
+
+subroutine test_nonexist_unknown_file()
+integer :: ierr
+type(netcdf_file) :: h
+
+call h%initialize('not-exist.nc', ierr, status='unknown', action='read')
+if (ierr==NF90_NOERR) error stop 'should have had ierr/=0 on non-existing unknown read file'
+end subroutine test_nonexist_unknown_file
+
+
+subroutine test_nonnetcdf_file()
+integer :: u,ierr
+type(netcdf_file) :: h
+character(*), parameter :: filename = 'bad.nc'
+
+! create or replace zero-length file, could be any size, just not a valid NetCDF file
+open(newunit=u, file=filename, status='replace', action='write')
+close(u)
+
+call h%initialize(filename, ierr, status='old', action='read')
+if (ierr==NF90_NOERR) error stop 'should have had ierr/=0 on invalid NetCDF file'
+end subroutine test_nonnetcdf_file
+
+
+subroutine test_nonexist_variable()
+integer :: u,ierr
+type(netcdf_file) :: h
+character(*), parameter :: filename = 'bad.nc'
+
+call h%initialize(filename, status='replace')
+call h%read('/not-exist', u, ierr)
+if (ierr==NF90_NOERR) error stop 'test_nonexist_variable: should have ierr/=0 on non-exist variable'
+call h%finalize()
+end subroutine test_nonexist_variable
+
+
+subroutine test_wrong_type()
+integer :: u
+type(netcdf_file) :: h
+character(*), parameter :: filename = 'bad.nc'
+
+call h%initialize(filename, status='replace')
+call h%write('real32', 42.)
+call h%finalize()
+
+call h%initialize(filename, status='old', action='read')
+call h%read('real32', u)
+if (u /= 42) error stop 'test_wrong_type: did not coerce real to integer'
+call h%finalize()
+
+end subroutine test_wrong_type
+
+
+subroutine test_unknown_write()
+integer :: ierr
+type(netcdf_file) :: h
+character(*), parameter :: filename = 'bad.nc'
+complex :: x
+
+x = (1, -1)
+
+call h%initialize(filename, ierr, status='replace')
+call h%write('/complex', x, ierr)
+if(ierr==NF90_NOERR) error stop 'test_unknown_write: writing unknown type variable'
+end subroutine test_unknown_write
+
+
+subroutine test_unknown_read()
+integer :: ierr
+type(netcdf_file) :: h
+character(*), parameter :: filename = 'bad.nc'
+complex :: x
+
+x = (1, -1)
+
+call h%initialize(filename, status='unknown', action='readwrite')
+call h%read('/complex', x, ierr)
+if(ierr==NF90_NOERR) error stop 'test_unknown_read: reading unknown type variable'
+end subroutine test_unknown_read
+
+end program