|
| 1 | +# Functions used for generating and installing ldc2.conf |
| 2 | + |
| 3 | +function(defineIfUnset variable) |
| 4 | + if(ARGC EQUAL 1) |
| 5 | + set(args) |
| 6 | + else() |
| 7 | + list(SUBLIST ARGV 1 -1 args) |
| 8 | + endif() |
| 9 | + |
| 10 | + if(NOT DEFINED ${variable}) |
| 11 | + set(${variable} ${args} PARENT_SCOPE) |
| 12 | + endif() |
| 13 | +endfunction() |
| 14 | + |
| 15 | +function(formatArray out_var) |
| 16 | + if(ARGC EQUAL 1) |
| 17 | + set(${out_var} "[]" PARENT_SCOPE) |
| 18 | + return() |
| 19 | + endif() |
| 20 | + |
| 21 | + list(SUBLIST ARGV 1 -1 values) |
| 22 | + set(result "[") |
| 23 | + foreach(value ${values}) |
| 24 | + set(result "${result}\n \"${value}\",") |
| 25 | + endforeach() |
| 26 | + set(result "${result}\n ]") |
| 27 | + |
| 28 | + set(${out_var} "${result}" PARENT_SCOPE) |
| 29 | +endfunction() |
| 30 | + |
| 31 | +function(formatArraySetting out_var name) |
| 32 | + if(ARGC EQUAL 2) |
| 33 | + # Ignore `value ~= []` |
| 34 | + set(${out_var} "" PARENT_SCOPE) |
| 35 | + return() |
| 36 | + endif() |
| 37 | + |
| 38 | + list(SUBLIST ARGV 2 -1 values) |
| 39 | + list(GET values 0 maybe_override) |
| 40 | + if(maybe_override STREQUAL "OVERRIDE") |
| 41 | + set(operator "=") |
| 42 | + list(POP_FRONT values) |
| 43 | + else() |
| 44 | + set(operator "~=") |
| 45 | + endif() |
| 46 | + formatArray(array ${values}) |
| 47 | + set(${out_var} "\n ${name} ${operator} ${array};" PARENT_SCOPE) |
| 48 | +endfunction() |
| 49 | + |
| 50 | +function(formatScalarSetting out_var name) |
| 51 | + if(ARGC EQUAL 2) |
| 52 | + set(${out_var} "" PARENT_SCOPE) |
| 53 | + else() |
| 54 | + set(${out_var} "\n ${name} = \"${ARGV2}\";" PARENT_SCOPE) |
| 55 | + endif() |
| 56 | +endfunction() |
| 57 | + |
| 58 | + |
| 59 | +# Create a ldc2.conf section |
| 60 | +# |
| 61 | +# Example: |
| 62 | +# |
| 63 | +# makeConfSectionImpl( |
| 64 | +# FILEPATH "${CMAKE_BINARY_DIR}/ldc2.conf" |
| 65 | +# # The output filename |
| 66 | +# |
| 67 | +# SECTION "^wasm(32|64)-" |
| 68 | +# # A regex to match a target triple or "default" |
| 69 | +# |
| 70 | +# SWITCHES -d-version=foo -L--linker-flag |
| 71 | +# # The `switches` list |
| 72 | +# |
| 73 | +# POST_SWITCHES OVERRIDE -I/path/to/druntime/src |
| 74 | +# # The `post-switches` list |
| 75 | +# |
| 76 | +# LIB_DIRS "${CMAKE_BINARY_DIR}/lib64" |
| 77 | +# # The `lib-dirs` list |
| 78 | +# |
| 79 | +# RPATH "/path/to/dir" |
| 80 | +# # The `rpath` value |
| 81 | +# ) |
| 82 | +# |
| 83 | +# Would generate: |
| 84 | +# |
| 85 | +# $ cat "${CMAKE_BINARY_DIR}/ldc2.conf" |
| 86 | +# "^wasm(32|64)-": |
| 87 | +# { |
| 88 | +# switches ~= [ |
| 89 | +# "-d-version=foo", |
| 90 | +# "-L--linker-flag", |
| 91 | +# ]; |
| 92 | +# post-switches = [ |
| 93 | +# "-I/path/to/druntime/src" |
| 94 | +# ]; |
| 95 | +# lib-dirs ~= [ |
| 96 | +# "${CMAKE_BINARY_DIR}/lib64" |
| 97 | +# ]; |
| 98 | +# rpath = "/path/to/dir" |
| 99 | +# } |
| 100 | +# |
| 101 | +# You don't need to pass all setting keys, only the ones that have values. |
| 102 | +# |
| 103 | +# Array settings (SWITCHES, POST_SWITCHES, LIB_DIRS) may start with an |
| 104 | +# OVERRIDE signifying that they should overwrite the (possibly) |
| 105 | +# previously stored values. The default is to append to them. |
| 106 | +function(makeConfSectionImpl) |
| 107 | + set(oneValueArgs FILEPATH SECTION RPATH) |
| 108 | + set(multiValueArgs SWITCHES POST_SWITCHES LIB_DIRS) |
| 109 | + cmake_parse_arguments(args "" "${oneValueArgs}" "${multiValueArgs}" ${ARGN}) |
| 110 | + |
| 111 | + foreach(var FILEPATH SECTION) |
| 112 | + if(NOT DEFINED args_${var}) |
| 113 | + message(SEND_ERROR "Expected ${var} argument") |
| 114 | + endif() |
| 115 | + endforeach() |
| 116 | + if(DEFINED args_UNPARSED_ARGUMENTS) |
| 117 | + message(SEND_ERROR "Unexpected arguments: ${args_UNPARSED_ARGUMENTS}") |
| 118 | + endif() |
| 119 | + |
| 120 | + formatArraySetting(switches "switches" ${args_SWITCHES}) |
| 121 | + formatArraySetting(post_switches "post-switches" ${args_POST_SWITCHES}) |
| 122 | + formatArraySetting(lib_dirs "lib-dirs" ${args_LIB_DIRS}) |
| 123 | + # Support `RPATH ""` to clear the setting |
| 124 | + set(rpath) |
| 125 | + if(args_RPATH OR "RPATH" IN_LIST args_KEYWORDS_MISSING_VALUES) |
| 126 | + formatScalarSetting(rpath "rpath" "${args_RPATH}") |
| 127 | + endif() |
| 128 | + |
| 129 | + file(WRITE "${args_FILEPATH}" |
| 130 | + "\"${args_SECTION}\":\n" |
| 131 | + "{" |
| 132 | + "${switches}" |
| 133 | + "${post_switches}" |
| 134 | + "${lib_dirs}" |
| 135 | + "${rpath}" |
| 136 | + "\n};\n" |
| 137 | + ) |
| 138 | +endfunction() |
| 139 | + |
| 140 | +# Create a ldc2.conf section |
| 141 | +# |
| 142 | +# Example: |
| 143 | +# |
| 144 | +# makeConfSection( |
| 145 | +# NAME 40-runtime |
| 146 | +# # a unique name for the file that will store this section |
| 147 | +# |
| 148 | +# SECTION "x86_64-.*-linux-gnu" |
| 149 | +# # A regex for a target triple or the string "default" |
| 150 | +# |
| 151 | +# BUILD |
| 152 | +# # Settings for ldc2.conf when part of this cmake project |
| 153 | +# SWITCHES -a -b |
| 154 | +# POST_SWITCHES -I${CMAKE_SOURCE_DIR}/runtime/import -c |
| 155 | +# |
| 156 | +# INSTALL |
| 157 | +# # Settings for ldc2.conf when installed on a user system |
| 158 | +# SWITCHES OVERRIDE -bar |
| 159 | +# LIB_DIRS "${CMAKE_INSTALL_PREFIX}/lib" |
| 160 | +# RPATH "${CMAKE_INSTALL_PREFIX}/lib" |
| 161 | +# ) |
| 162 | +# |
| 163 | +# The possible settings are described by makeConfSectionImpl. |
| 164 | +# |
| 165 | +# As a shortcut the BUILD and INSTALL arguments may be omitted, making the |
| 166 | +# settings be applied to both build and install ldc2.conf. Example: |
| 167 | +# |
| 168 | +# makeConfSection(NAME 10-example SECTION default |
| 169 | +# SWITCHES -my-important-switch |
| 170 | +# ) |
| 171 | +# |
| 172 | +# Is equivalent to: |
| 173 | +# |
| 174 | +# makeConfSection(NAME 10-example SECTION default |
| 175 | +# BUILD |
| 176 | +# SWITCHES -my-important-switch |
| 177 | +# INSTALL |
| 178 | +# SWITCHES -my-important-switch |
| 179 | +# ) |
| 180 | +# |
| 181 | +# It is also possible to generate a configuration file for either only the build |
| 182 | +# or only the install. Simply pass only BUILD or INSTALL to this function. |
| 183 | +function(makeConfSection) |
| 184 | + set(oneValueArgs NAME SECTION) |
| 185 | + set(multiValueArgs BUILD INSTALL) |
| 186 | + cmake_parse_arguments(PARSE_ARGV 0 args "" "${oneValueArgs}" "${multiValueArgs}") |
| 187 | + |
| 188 | + foreach(var ${oneValueArgs}) |
| 189 | + if(NOT DEFINED args_${var}) |
| 190 | + message(SEND_ERROR "Expected defined ${var} argument") |
| 191 | + endif() |
| 192 | + endforeach() |
| 193 | + if(DEFINED args_UNPARSED_ARGUMENTS) |
| 194 | + if(NOT DEFINED args_BUILD AND NOT DEFINED args_INSTALL) |
| 195 | + set(args_BUILD "${args_UNPARSED_ARGUMENTS}") |
| 196 | + set(args_INSTALL "${args_UNPARSED_ARGUMENTS}") |
| 197 | + else() |
| 198 | + message(SEND_ERROR "Unexpected arguments: ${args_UNPARSED_ARGUMENTS}") |
| 199 | + endif() |
| 200 | + endif() |
| 201 | + |
| 202 | + if(args_BUILD) |
| 203 | + set(build_conf "${LDC_BUILD_CONF}/${args_NAME}.conf") |
| 204 | + makeConfSectionImpl(FILEPATH "${build_conf}" SECTION "${args_SECTION}" ${args_BUILD}) |
| 205 | + endif() |
| 206 | + if(args_INSTALL) |
| 207 | + set(install_conf "${LDC_INSTALL_CONF}/${args_NAME}.conf") |
| 208 | + makeConfSectionImpl(FILEPATH "${install_conf}" SECTION "${args_SECTION}" ${args_INSTALL}) |
| 209 | + if(NOT DONT_INSTALL_CONF) |
| 210 | + install(FILES "${install_conf}" DESTINATION "${CONF_INST_DIR}/ldc2.conf") |
| 211 | + endif() |
| 212 | + endif() |
| 213 | +endfunction() |
| 214 | + |
| 215 | +# Generally, we want to install everything into CMAKE_INSTALL_PREFIX, but when |
| 216 | +# it is /usr, put the config files into /etc to meet common practice. |
| 217 | +if(NOT DEFINED SYSCONF_INSTALL_DIR) |
| 218 | + if(CMAKE_INSTALL_PREFIX STREQUAL "/usr") |
| 219 | + set(SYSCONF_INSTALL_DIR "/etc") |
| 220 | + else() |
| 221 | + set(SYSCONF_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/etc") |
| 222 | + endif() |
| 223 | +endif() |
| 224 | + |
| 225 | +set(CONF_INST_DIR ${SYSCONF_INSTALL_DIR} CACHE PATH "Directory in which to install ldc2.conf") |
| 226 | +if(CONF_INST_DIR STREQUAL "") |
| 227 | + set(DONT_INSTALL_CONF TRUE) |
| 228 | +else() |
| 229 | + set(DONT_INSTALL_CONF FALSE) |
| 230 | +endif() |
| 231 | + |
| 232 | +set(INCLUDE_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include/d CACHE PATH "Path to install D modules to") |
| 233 | + |
| 234 | +defineIfUnset(LDC_BUILD_CONF "${CMAKE_BINARY_DIR}/etc/ldc2.conf") |
| 235 | +defineIfUnset(LDC_INSTALL_CONF "${CMAKE_BINARY_DIR}/etc/ldc2_install.conf") |
0 commit comments