get, set, modify, insert, delete (#1)

* get and set functions

* Typo

* eslint

* Tests

* RowLacks for insert

* Remove unused type arg

Author: paf31

bower.json

@@ -15,5 +15,13 @@
     "test",
     "bower.json",
     "package.json"
-  ]
+  ],
+  "dependencies": {
+    "purescript-symbols": "^3.0.0",
+    "purescript-functions": "^3.0.0",
+    "purescript-typelevel-prelude": "^2.3.1"
+  },
+  "devDependencies": {
+    "purescript-assert": "^3.0.0"
+  }
 }

src/Data/Record.js

@@ -0,0 +1,26 @@
+"use strict";
+
+exports.unsafeGet = function(label, rec) {
+  return rec[label];
+};
+
+exports.unsafeSet = function(label, value, rec) {
+  var copy = {};
+  for (var key in rec) {
+    if ({}.hasOwnProperty.call(rec, key)) {
+      copy[key] = rec[key];
+    }
+  }
+  copy[label] = value;
+  return copy;
+};
+
+exports.unsafeDelete = function(label, rec) {
+  var copy = {};
+  for (var key in rec) {
+    if (key !== label && {}.hasOwnProperty.call(rec, key)) {
+      copy[key] = rec[key];
+    }
+  }
+  return copy;
+};

src/Data/Record.purs

@@ -1 +1,114 @@
-module Data.Record where
+module Data.Record
+  ( get
+  , set
+  , modify
+  , insert
+  , delete
+  ) where
+
+import Data.Function.Uncurried (Fn2, Fn3, runFn2, runFn3)
+import Data.Symbol (class IsSymbol, SProxy, reflectSymbol)
+import Type.Row (class RowLacks)
+
+foreign import unsafeGet :: forall r a. Fn2 String (Record r) a
+foreign import unsafeSet :: forall r1 r2 a. Fn3 String a (Record r1) (Record r2)
+foreign import unsafeDelete :: forall r1 r2. Fn2 String (Record r1) (Record r2)
+
+-- | Get a property for a label which is specified using a value-level proxy for
+-- | a type-level string.
+-- |
+-- | For example:
+-- |
+-- | ```purescript
+-- | get (SProxy :: SProxy "x") :: forall r a. { x :: a | r } -> a
+-- | ```
+get
+  :: forall r r' l a
+   . IsSymbol l
+  => RowCons l a r' r
+  => SProxy l
+  -> Record r
+  -> a
+get l r = runFn2 unsafeGet (reflectSymbol l) r
+
+-- | Set a property for a label which is specified using a value-level proxy for
+-- | a type-level string.
+-- |
+-- | For example:
+-- |
+-- | ```purescript
+-- | set (SProxy :: SProxy "x")
+-- |   :: forall r a b. a -> { x :: b | r } -> { x :: a | r }
+-- | ```
+set
+  :: forall r1 r2 r l a b
+   . IsSymbol l
+  => RowCons l a r r1
+  => RowCons l b r r2
+  => SProxy l
+  -> b
+  -> Record r1
+  -> Record r2
+set l b r = runFn3 unsafeSet (reflectSymbol l) b r
+
+-- | Modify a property for a label which is specified using a value-level proxy for
+-- | a type-level string.
+-- |
+-- | For example:
+-- |
+-- | ```purescript
+-- | modify (SProxy :: SProxy "x")
+-- |   :: forall r a b. (a -> b) -> { x :: a | r } -> { x :: b | r }
+-- | ```
+modify
+  :: forall r1 r2 r l a b
+   . IsSymbol l
+  => RowCons l a r r1
+  => RowCons l b r r2
+  => SProxy l
+  -> (a -> b)
+  -> Record r1
+  -> Record r2
+modify l f r = set l (f (get l r)) r
+
+-- | Insert a new property for a label which is specified using a value-level proxy for
+-- | a type-level string.
+-- |
+-- | For example:
+-- |
+-- | ```purescript
+-- | insert (SProxy :: SProxy "x")
+-- |   :: forall r a. a -> { | r } -> { x :: a | r }
+-- | ```
+insert
+  :: forall r1 r2 l a
+   . IsSymbol l
+  => RowLacks l r1
+  => RowCons l a r1 r2
+  => SProxy l
+  -> a
+  -> Record r1
+  -> Record r2
+insert l a r = runFn3 unsafeSet (reflectSymbol l) a r
+
+-- | Delete a property for a label which is specified using a value-level proxy for
+-- | a type-level string.
+-- |
+-- | Note that the type of the resulting row must _lack_ the specified property.
+-- | Since duplicate labels are allowed, this is checked with a type class constraint.
+-- |
+-- | For example:
+-- |
+-- | ```purescript
+-- | delete (SProxy :: SProxy "x")
+-- |   :: forall r a. RowLacks "x" r => { x :: a | r } -> { | r }
+-- | ```
+delete
+  :: forall r1 r2 l a
+   . IsSymbol l
+  => RowLacks l r1
+  => RowCons l a r1 r2
+  => SProxy l
+  -> Record r2
+  -> Record r1
+delete l r = runFn2 unsafeDelete (reflectSymbol l) r

test/Main.purs

@@ -0,0 +1,24 @@
+module Test.Main where
+
+import Prelude
+
+import Control.Monad.Eff (Eff)
+import Data.Record (delete, get, insert, modify, set)
+import Data.Symbol (SProxy(..))
+import Test.Assert (ASSERT, assert')
+
+main :: Eff (assert :: ASSERT) Unit
+main = do
+  let x = SProxy :: SProxy "x"
+      y = SProxy :: SProxy "y"
+
+  assert' "insert, get" $
+    get x (insert x 42 {}) == 42
+  assert' "insert, modify, get" $
+    get x (modify x (_ + 1) (insert x 42 {})) == 43
+  assert' "set, get" $
+    get x (set x 0 { x: 42 }) == 0
+  assert' "set, modify, get" $
+    get x (modify x (_ + 1) (set x 0 { x: 42 })) == 1
+  assert' "delete, get" $
+    get x (delete y { x: 42, y: 1337 }) == 42