Add support for new elevation and CNR commands

Author: nseidle

examples/2. Configuration/ElevationCNR/ElevationCNR.ino

@@ -0,0 +1,118 @@
+/*
+  Configuring minimum elevation and CNR used in the positioning engine
+  By: Nathan Seidle + Mikal Hart
+  SparkFun Electronics
+  Date: 20 May 2025
+  License: MIT. Please see LICENSE.md for more information.
+
+  This example shows how to configure the min elevation and CNR used for the position engine.
+
+  It is a known practice to raise the minimum elevation from the default of 5 degrees to 10 or even 15 degrees 
+  when in an urban environment to exclude satellites that are too low and may be blocked by structures causing 
+  multipath errors. Similarly, increasing the minimum CNR from 10 dBHz to 20 or 25 dBHz can exclude satellites
+  with lower signal strength from being used in the position calculation.
+
+  The LG290P firmware must be v5 ("LG290P03AANR01A05S") or higher for these commands to work. We recommend using the QGNSS software
+  to update the LG290P firmware.
+  Latest Firmware: https://github.com/sparkfun/SparkFun_RTK_Postcard/tree/main/Firmware
+  Docs: https://docs.sparkfun.com/SparkFun_LG290P_Quadband_GNSS_RTK_Breakout/software_overview/#qgnss-software
+
+  These examples are targeted for an ESP32 platform but any platform that has multiple
+  serial UARTs should be compatible.
+
+  Feel like supporting open source hardware?
+  Buy a board from SparkFun!
+  SparkFun Quadband GNSS RTK Breakout - LG290P (GPS-26620) https://www.sparkfun.com/products/26620
+
+  Hardware Connections:
+  Connect RX3 (green wire) of the LG290P to pin 14 on the ESP32
+  Connect TX3 (orange wire) of the LG290P to pin 13 on the ESP32
+  To make this easier, a 4-pin locking JST cable can be purchased here: https://www.sparkfun.com/products/17240
+  Note: Almost any ESP32 pins can be used for serial.
+  Connect a multi-band GNSS antenna: https://www.sparkfun.com/products/21801
+*/
+
+#include <SparkFun_LG290P_GNSS.h> // Click here to get the library: http://librarymanager/All#SparkFun_LG290P
+
+// Adjust these values according to your configuration
+int pin_UART1_TX = 14;
+int pin_UART1_RX = 13;
+int gnss_baud = 460800;
+
+LG290P myGNSS;
+HardwareSerial SerialGNSS(1); // Use UART1 on the ESP32
+
+void setup()
+{
+  Serial.begin(115200);
+  delay(250);
+  Serial.println();
+  Serial.println("SparkFun Elevation and CNR example");
+  Serial.println("Initializing device...");
+
+  // We must start the serial port before using it in the library
+  // Increase buffer size to handle high baud rate streams
+  SerialGNSS.setRxBufferSize(1024);
+  SerialGNSS.begin(gnss_baud, SERIAL_8N1, pin_UART1_RX, pin_UART1_TX);
+
+  // myGNSS.enableDebugging(Serial); // Print all debug to Serial
+  if (myGNSS.begin(SerialGNSS) == false)     // Give the serial port over to the library
+  {
+    Serial.println("LG290P failed to respond. Check ports and baud rates. Freezing...");
+    while (true);
+  }
+  Serial.println("LG290P detected!");
+
+  int elevationAngle = 0;
+  if (myGNSS.getElevationAngle(elevationAngle) == false)
+  {
+    Serial.println("Failed to read elevation angle. Do you have version 5 or newer of the LG290P firmware installed?");
+  }
+  else
+  {
+    Serial.printf("Successfully checked elevation angle: %d degrees\r\n", elevationAngle);
+    
+    // 5 is default meaning any satellite 5 degrees above the horizon or higher will be used
+    // 90 to -90 is allowed
+    if (myGNSS.setElevationAngle(10) == false)
+      Serial.println("Failed to set elevation angle");
+    else
+    {
+      if (myGNSS.getElevationAngle(elevationAngle) == false)
+        Serial.println("Failed to read elevation angle.");
+      else
+      {
+        Serial.printf("Elevation angle set to %d degrees.\r\n", elevationAngle);
+      }
+    }
+  }
+
+  float cnr = 0;
+  if (myGNSS.getCNR(cnr) == false)
+  {
+    Serial.println("Failed to read CNR. Do you have version 5 or newer of the LG290P firmware installed?");
+  }
+  else
+  {
+    Serial.printf("Successfully checked CNR: %0.1f dBHz\r\n", cnr);
+    
+    // 10.0 is default meaning any satellite with greater than 10 dBHz signal level will be included in the position fix calculation
+    // 0.0 to 99.0 dBHz is allowed
+    if (myGNSS.setCNR(15.0) == false)
+      Serial.println("Failed to set CNR");
+    else
+    {
+      if (myGNSS.getCNR(cnr) == false)
+        Serial.println("Failed to read CNR.");
+      else
+      {
+        Serial.printf("CNR set to %0.1f dBHz.\r\n", cnr);
+      }
+    }
+  }  
+}
+
+void loop()
+{
+
+}

keywords.txt

@@ -146,6 +146,11 @@ getProtLevelEastVelocity	KEYWORD2
 getProtLevelDownVelocity	KEYWORD2
 getProtLevelTime	KEYWORD2
 
+setElevationAngle	KEYWORD2
+getElevationAngle	KEYWORD2
+setCNR	KEYWORD2
+getCNR	KEYWORD2
+
 #######################################
 # Constants (LITERAL1)
 #######################################

library.properties

@@ -1,5 +1,5 @@
 name=SparkFun LG290P Quadband RTK GNSS Arduino Library
-version=1.0.4
+version=1.0.5
 author=SparkFun Electronics
 maintainer=SparkFun Electronics <sparkfun.com>
 sentence=Library for Serial Communication and Configuration of the LG290P

src/SparkFun_LG290P_GNSS.cpp

@@ -665,6 +665,46 @@ bool LG290P::getMessageRate(const char *msgName, int &rate, int msgVer)
     return ret;
 }
 
+// Configures the elevation threshold for position engine. Available in v5 and above.
+bool LG290P::setElevationAngle(int elevationAngle)
+{
+    char parms[50];
+    snprintf(parms, sizeof parms, ",W,%d", elevationAngle);
+    return sendOkCommand("PQTMCFGELETHD", parms) && hotStart();
+}
+
+bool LG290P::getElevationAngle(int &elevationAngle)
+{
+    bool ret = sendCommand("PQTMCFGELETHD", ",R");
+    if (ret)
+    {
+        auto packet = getCommandResponse();
+        ret = packet[1] == "OK";
+        elevationAngle = atoi(packet[2].c_str());
+    }
+    return ret;
+}
+
+// Configures the CNR threshold for position engine. Available in v5 and above.
+bool LG290P::setCNR(float cnr)
+{
+    char parms[50];
+    snprintf(parms, sizeof parms, ",W,%0.2f", cnr);
+    return sendOkCommand("PQTMCFGCNRTHD", parms) && hotStart();
+}
+
+bool LG290P::getCNR(float &cnr)
+{
+    bool ret = sendCommand("PQTMCFGCNRTHD", ",R");
+    if (ret)
+    {
+        auto packet = getCommandResponse();
+        ret = packet[1] == "OK";
+        cnr = atof(packet[2].c_str());
+    }
+    return ret;
+}
+
 bool LG290P::scanForMsgsEnabled()
 {
     bool ok = getMessageRate("GGA", devState.ggaRate);

src/SparkFun_LG290P_GNSS.h

@@ -407,8 +407,40 @@ class LG290P
     bool getFixInterval(uint16_t &fixInterval);
 
     /**
-     * @brief Sets a new fix interval.
-     * @details Uses the PQTMCFGFIXRATE command. Use a value between 25 and 1000
+     * @brief Sets a new elevation threshold for position engine.
+     * @details Uses the PQTMCFGELETHD command. Use a value between -90 and 90. Default is 5 degrees.
+     * @param elevationAngle The new elevation threshold for the position engine.
+     * @return true if successful, false otherwise.
+     */
+    bool setElevationAngle(int elevationAngle);
+
+        /**
+     * @brief Gets the elevation threshold for position engine.
+     * @details Uses the PQTMCFGELETHD command.
+     * @param elevationAngle Reference to a int where the elevation angle (degrees) will be stored.
+     * @return true if successful, false otherwise.
+     */
+    bool getElevationAngle(int &elevationAngle);
+
+        /**
+     * @brief Sets the CNR threshold for position engine.
+     * @details Uses the PQTMCFGCNRTHD command. Use a value between 0.0 and 99.0. Default is 10.0 dBHz.
+     * @param cnr The new CNR threshold for the position engine.
+     * @return true if successful, false otherwise.
+     */
+    bool setCNR(float cnr);
+
+        /**
+     * @brief Gets the CNR threshold for position engine.
+     * @details Uses the PQTMCFGCNRTHD command.
+     * @param cnr Reference to a float where the CNR value will be stored.
+     * @return true if successful, false otherwise.
+     */
+    bool getCNR(float &cnr);
+
+    /**
+     * @brief Sets a new elevation threshold for position engine.
+     * @details Uses the PQTMCFGELETHD command. Use a value between -90 and 90
      * @param fixInterval The new fix interval to set.
      * @return true if successful, false otherwise.
      */