Fix 5.42 regression with strftime() and daylight savings

ext/POSIX/POSIX.xs

@@ -3589,7 +3589,7 @@ difftime(time1, time2)
 #     sv_setpv(TARG, ...) could be used rather than
 #     ST(0) = sv_2mortal(newSVpv(...))
 void
-strftime(fmt, sec, min, hour, mday, mon, year, wday = -1, yday = -1, isdst = 0)
+strftime(fmt, sec, min, hour, mday, mon, year, wday = -1, yday = -1, isdst = -1)
 	SV *		fmt
 	int		sec
 	int		min
@@ -3605,10 +3605,8 @@ strftime(fmt, sec, min, hour, mday, mon, year, wday = -1, yday = -1, isdst = 0)
             PERL_UNUSED_ARG(wday);
             PERL_UNUSED_ARG(yday);
 
-            /* -isdst triggers backwards compatibility mode for non-zero
-             * 'isdst' */
             SV *sv = sv_strftime_ints(fmt, sec, min, hour, mday, mon, year,
-                                           -abs(isdst));
+                                      isdst);
 	    if (sv) {
                 sv = sv_2mortal(sv);
             }

ext/POSIX/lib/POSIX.pm

@@ -4,7 +4,7 @@ use warnings;
 
 our ($AUTOLOAD, %SIGRT);
 
-our $VERSION = '2.24';
+our $VERSION = '2.25';
 
 require XSLoader;
 

ext/POSIX/lib/POSIX.pod

@@ -1866,49 +1866,17 @@ Identical to the string form of C<$!>, see L<perlvar/$ERRNO>.
 =item C<strftime>
 
 Convert date and time information to string based on the current
-underlying locale of the program (except for any daylight savings time).
-Returns the string.
+underlying locale of the program.
+Returns the string in a mortalized SV; set to an empty string on error.
 
-Synopsis:
-
-	strftime(fmt, sec, min, hour, mday, mon, year,
-		 wday = -1, yday = -1, isdst = 0)
-
-The month (C<mon>) begins at zero,
-I<e.g.>, January is 0, not 1.  The
-year (C<year>) is given in years since 1900, I<e.g.>, the year 1995 is 95; the
-year 2001 is 101.  Consult your system's C<strftime()> manpage for details
-about these and the other arguments.
+ my $sv = strftime(fmt, sec, min, hour, mday, mon, year,
+                   wday = -1, yday = -1, isdst = -1)
 
 The C<wday> and C<yday> parameters are both ignored.  Their values are
 always determinable from the other parameters.
 
-C<isdst> should be C<1> or C<0>, depending on whether or not daylight
-savings time is in effect for the given time or not.
-
-If you want your code to be portable, your format (C<fmt>) argument
-should use only the conversion specifiers defined by the ANSI C
-standard (C99, to play safe).  These are C<aAbBcdHIjmMpSUwWxXyYZ%>.
-But even then, the B<results> of some of the conversion specifiers are
-non-portable.  For example, the specifiers C<aAbBcpZ> change according
-to the locale settings of the user, and both how to set locales (the
-locale names) and what output to expect are non-standard.
-The specifier C<c> changes according to the timezone settings of the
-user and the timezone computation rules of the operating system.
-The C<Z> specifier is notoriously unportable since the names of
-timezones are non-standard. Sticking to the numeric specifiers is the
-safest route.
-
-The arguments, except for C<isdst>, are made consistent as though by
-calling C<mktime()> before calling your system's C<strftime()> function.
-To get correct results, you must set C<isdst> to be the proper value.
-When omitted, the function assumes daylight savings is not in effect.
-
-The string for Tuesday, December 12, 1995 in the C<C> locale.
-
-	$str = POSIX::strftime( "%A, %B %d, %Y",
-				 0, 0, 0, 12, 11, 95, 2 );
-	print "$str\n";
+More details on the behavior and the specification of the other
+parameters are described in L<perlapi/sv_strftime_ints>.
 
 =item C<strlen>
 

ext/POSIX/t/posix.t

@@ -273,7 +273,12 @@ print POSIX::strftime("ok $test # %H:%M, on %m/%d/%y\n", localtime());
 # input fields to strftime().
 sub try_strftime {
     my $expect = shift;
-    my $got = POSIX::strftime("%a %b %d %H:%M:%S %Y %j", @_);
+    my @input = @_;
+
+    # Add zeros to missing parameters.  The final 0 is for isdst, and the zero
+    # forces use of mini_mktime (unless the code changes).
+    push @input, 0 while @input < 9;
+    my $got = POSIX::strftime("%a %b %d %H:%M:%S %Y %j", @input);
     is($got, $expect, "validating mini_mktime() and strftime(): $expect");
 }
 

ext/POSIX/t/time.t

@@ -9,21 +9,23 @@ use strict;
 
 use Config;
 use POSIX;
-use Test::More tests => 31;
+use Test::More tests => 49;
 
 # For the first go to UTC to avoid DST issues around the world when testing.  SUS3 says that
 # null should get you UTC, but some environments want the explicit names.
 # Those with a working tzset() should be able to use the TZ below.
 $ENV{TZ} = "EST5EDT";
 
+# It looks like POSIX.xs claims that only VMS and Mac OS traditional
+# don't have tzset().  MingW doesn't work.  Cygwin works in some places, but
+# not others.  The other Win32's below are guesses.
+my $has_tzset = $^O ne "VMS" && $^O ne "cygwin"
+             && ($^O ne "MSWin32" || (   $^O eq "MSWin32"
+                                      && $Config{make} eq 'nmake'))
+             && $^O ne "interix";
+
 SKIP: {
-    # It looks like POSIX.xs claims that only VMS and Mac OS traditional
-    # don't have tzset().  Win32 works to call the function, but it doesn't
-    # actually do anything.  Cygwin works in some places, but not others.  The
-    # other Win32's below are guesses.
-    skip "No tzset()", 1
-       if $^O eq "VMS" || $^O eq "cygwin" ||
-          $^O eq "MSWin32" || $^O eq "interix";
+    skip "No tzset()", 1 unless $has_tzset;
     tzset();
     SKIP: {
         my @tzname = tzname();
@@ -42,9 +44,7 @@ SKIP: {
 $ENV{TZ} = "UTC0UTC";
 
 SKIP: {
-    skip "No tzset()", 2
-       if $^O eq "VMS" || $^O eq "cygwin" ||
-          $^O eq "MSWin32" || $^O eq "interix";
+    skip "No tzset()", 2 unless $has_tzset;
     tzset();
     my @tzname = tzname();
     like($tzname[0], qr/(GMT|UTC)/i, "tzset() to GMT/UTC");
@@ -205,7 +205,7 @@ SKIP: {
     is(mktime(CORE::localtime($time)), $time, "mktime()");
     is(mktime(POSIX::localtime($time)), $time, "mktime()");
 }
- 
+
 SKIP: {
     skip "'%s' not implemented in strftime", 1 if $^O eq "VMS"
                                                || $^O eq "MSWin32"
@@ -226,3 +226,122 @@ SKIP: {
     is(strftime(undef, CORE::localtime), '', "strftime() works if format is undef");
     like($warnings, qr/^Use of uninitialized value in subroutine entry /, "strftime(undef, ...) produces expected warning");
 }
+
+# Now check the transitioning between standard and daylight savings times.  To
+# do this requires setting a timezone.  Unfortunately, timezone specification
+# syntax differs incompatibly between systems.  The older PST8PDT style
+# prevails on Windows, but is being supplanted by "Europe/Paris" style
+# elsewhere.  Debian in particular requires a special package to be installed
+# to correctly work with the old style.  Worse, without the package, it still
+# can recognize the syntax and correctly get right times that aren't at the
+# edge of the transitions.  khw tried the 2004 and 2025 spring forward times,
+# and Debian sans-package was exactly 6 hours off the correct values.
+# (The older style was U.S. centric, assuming everyone in the world with the
+# same longitude obeyed the same rules; the new style can tailor the rules to
+# the specific region affected.)
+
+# Tue 01 Jul 2025 05:01:01 PM GMT.  This is chosen as being in the middle of
+# Daylight Savings Time.  Below, we set locales, and verify that these
+# actually worked by checking that the hour returned is the expected value.
+my $reference_time = 1751389261;
+
+my $new_names_all_passed = 0;
+my $some_new_name_passed = 0;
+
+SKIP: {   # GH #23878; test that dst fall back works properly
+    my $skip_count = 9;
+    skip "No mktime()", $skip_count if $Config{d_mktime} ne 'define';
+
+    # Doing this ensures that Windows is expecting a different timezone than
+    # the one in the test.  Hence, if the new-style name isn't recognized, the
+    # tests will be skipped.  Otherwise, if the test happens to being run on a
+    # platform located in the Paris timezone, the check will happen to
+    # succeed even though the timezone change failed.
+    $ENV{TZ} = "PST8PDT";
+    tzset() if $has_tzset;
+
+    my $locale = "Europe/Paris";
+    $ENV{TZ} = $locale;
+    tzset() if $has_tzset;
+
+    skip "'$locale' not understood", $skip_count
+                   if POSIX::strftime("%H", localtime($reference_time)) != 19;
+
+    my $t = 1761436800;     # an hour before time should have changed
+    my @fall = (
+                 [   -1, "2025-10-26 01:59:59+0200", "Chg -1 hr, 1 sec" ],
+                 [    0, "2025-10-26 02:00:00+0200", "Chg -1 hr, 0 sec" ],
+                 [    1, "2025-10-26 02:00:01+0200", "Chg -59 min, 59 sec" ],
+                 [ 3599, "2025-10-26 02:59:59+0200", "Chg -1 sec" ],
+                 [ 3600, "2025-10-26 02:00:00+0100", "At Paris DST fallback" ],
+                 [ 3601, "2025-10-26 02:00:01+0100", "Chg +1 sec" ],
+                 [ 7199, "2025-10-26 02:59:59+0100", "Chg +1 hr, 59m, 59s" ],
+                 [ 7200, "2025-10-26 03:00:00+0100", "Chg +1 hr" ],
+                 [ 7201, "2025-10-26 03:00:01+0100", "Chg +1 hr, 1 sec" ],
+               );
+    my $had_failure = 0;
+    for (my $i = 0; $i < @fall; $i++) {
+        if (is(POSIX::strftime("%F %T%z", localtime $t + $fall[$i][0]),
+               $fall[$i][1], $fall[$i][2]))
+        {
+            $some_new_name_passed = 1;
+        }
+        else {
+            $had_failure = 1
+        }
+    }
+
+    $new_names_all_passed = ! $had_failure;
+}
+
+SKIP: {   # GH #23878: test that dst spring forward works properly.
+    my $skip_count = 9;
+    skip "No mktime()", $skip_count if $Config{d_mktime} ne 'define';
+
+    my $locale;
+
+    # For this group of tests, we use the old-style timezone names on systems
+    # that don't understand the new ones, and use the new ones on systems that
+    # do; this finesses the problem of some systems needing special packages
+    # to handle old names properly.
+
+    # The group of tests just before this one set this variable.  If 'false'
+    # it means no new name worked, likely because they aren't understood, but
+    # also could be because of bugs.
+    if ($some_new_name_passed) {
+        skip "DST fall back didn't work; spring forward not tested",
+                                     $skip_count unless $new_names_all_passed;
+        $locale = "America/Los_Angeles";
+    }
+    else {
+
+        # Use a locale that MS narcissism should be able to handle
+        $locale = "PST8PDT";
+    }
+
+    $ENV{TZ} = $locale;
+    tzset() if $has_tzset;
+
+    # $reference_time is in the middle of summer, dst should be in effect.
+    skip "'$locale' not understood", $skip_count if
+                POSIX::strftime("%H", localtime($reference_time)) != 10;
+
+    my $t = 1741510800;     # an hour before time should have changed
+
+    my @spring = (
+                  [   -1, "2025-03-09 00:59:59-0800", "Chg -1 hr,-1 sec" ],
+                  [    0, "2025-03-09 01:00:00-0800", "Chg -1 hr, 0 sec" ],
+                  [    1, "2025-03-09 01:00:01-0800", "Chg -59 min,-59 sec" ],
+                  [ 3599, "2025-03-09 01:59:59-0800", "Chg -1 sec" ],
+                  [ 3600, "2025-03-09 03:00:00-0700",
+                                            "At Redmond DST spring forward" ],
+                  [  3601, "2025-03-09 03:00:01-0700", "Chg +1 sec" ],
+                  [  7199, "2025-03-09 03:59:59-0700", "Chg +1 hr, 59m,59s" ],
+                  [  7200, "2025-03-09 04:00:00-0700", "Chg +1 hr" ],
+                  [  7201, "2025-03-09 04:00:01-0700", "Chg +1 hr, 1 sec" ],
+            );
+    for (my $i = 0; $i < @spring; $i++) {
+        is(POSIX::strftime("%F %T%z", localtime $t + $spring[$i][0]),
+           $spring[$i][1], $spring[$i][2]);
+    }
+}