Add initial kotlin native toolchain and kt_library rule

MODULE.bazel

@@ -28,17 +28,27 @@ use_repo(
     "com_github_google_ksp",
     "com_github_jetbrains_kotlin",
     "com_github_jetbrains_kotlin_git",
+    "com_github_jetbrains_kotlin_native_linux_x86_64",
+    "com_github_jetbrains_kotlin_native_linux_x86_64_git",
+    "com_github_jetbrains_kotlin_native_macos_aarch64",
+    "com_github_jetbrains_kotlin_native_macos_aarch64_git",
+    "com_github_jetbrains_kotlin_native_macos_x86_64",
+    "com_github_jetbrains_kotlin_native_macos_x86_64_git",
+    "com_github_jetbrains_kotlin_native_windows_x86_64",
+    "com_github_jetbrains_kotlin_native_windows_x86_64_git",
     "com_github_pinterest_ktlint",
     "kotlin_build_tools_impl",
     "kotlinx_serialization_core_jvm",
     "kotlinx_serialization_json",
     "kotlinx_serialization_json_jvm",
 )
 
-register_toolchains("//src/main/starlark/core/compile/cli")
+register_toolchains("//src/main/starlark/core/compile/cli:all")
 
 register_toolchains("//kotlin/internal:default_toolchain")
 
+register_toolchains("//kotlin/internal/native:all")
+
 # Development dependencies
 # TODO(bencodes) A bunch of these dependencies need to be marked as dev_dependencies but before we can do that
 # we need to sort out a few cases around how these rules are consumed in various ways.

MODULE.release.bazel

@@ -31,6 +31,16 @@ use_repo(
     "kotlinx_serialization_json",
     "kotlinx_serialization_json_jvm",
     "kotlin_build_tools_impl",
+    "com_github_jetbrains_kotlin_native_linux_x86_64",
+    "com_github_jetbrains_kotlin_native_linux_x86_64_git",
+    "com_github_jetbrains_kotlin_native_macos_aarch64",
+    "com_github_jetbrains_kotlin_native_macos_aarch64_git",
+    "com_github_jetbrains_kotlin_native_macos_x86_64",
+    "com_github_jetbrains_kotlin_native_macos_x86_64_git",
+    "com_github_jetbrains_kotlin_native_windows_x86_64",
+    "com_github_jetbrains_kotlin_native_windows_x86_64_git",
 )
 
 register_toolchains("//kotlin/internal:default_toolchain")
+
+register_toolchains("//kotlin/internal/native:all")

docs/kotlin.md

@@ -562,7 +562,7 @@ load("@rules_kotlin//kotlin:core.bzl", "kt_register_toolchains")
 kt_register_toolchains()
 </pre>
 
-This macro registers the kotlin toolchain.
+This macro registers the kotlin/JVM toolchain and the kotlin native toolchain.
 
 
 
@@ -578,7 +578,9 @@ This macro registers the kotlin toolchain.
 load("@rules_kotlin//kotlin:repositories.doc.bzl", "kotlin_repositories")
 
 kotlin_repositories(<a href="#kotlin_repositories-is_bzlmod">is_bzlmod</a>, <a href="#kotlin_repositories-compiler_repository_name">compiler_repository_name</a>, <a href="#kotlin_repositories-ksp_repository_name">ksp_repository_name</a>, <a href="#kotlin_repositories-compiler_release">compiler_release</a>,
-                    <a href="#kotlin_repositories-ksp_compiler_release">ksp_compiler_release</a>)
+                    <a href="#kotlin_repositories-ksp_compiler_release">ksp_compiler_release</a>, <a href="#kotlin_repositories-kotlin_native_release_linux_x86_64">kotlin_native_release_linux_x86_64</a>,
+                    <a href="#kotlin_repositories-kotlin_native_release_macos_x86_64">kotlin_native_release_macos_x86_64</a>, <a href="#kotlin_repositories-kotlin_native_release_macos_aarch64">kotlin_native_release_macos_aarch64</a>,
+                    <a href="#kotlin_repositories-kotlin_native_release_windows_x86_64">kotlin_native_release_windows_x86_64</a>)
 </pre>
 
 Call this in the WORKSPACE file to setup the Kotlin rules.
@@ -593,6 +595,10 @@ Call this in the WORKSPACE file to setup the Kotlin rules.
 | <a id="kotlin_repositories-ksp_repository_name"></a>ksp_repository_name |  <p align="center"> - </p>   |  `"com_github_google_ksp"` |
 | <a id="kotlin_repositories-compiler_release"></a>compiler_release |  version provider from versions.bzl.   |  `struct(sha256 = "1ba08a8b45da99339a0601134cc037b54cf85e9bc0edbe76dcbd27c2d684a977", url_templates = ["https://github.com/JetBrains/kotlin/releases/download/v{version}/kotlin-compiler-{version}.zip"], version = "2.1.21")` |
 | <a id="kotlin_repositories-ksp_compiler_release"></a>ksp_compiler_release |  (internal) version provider from versions.bzl.   |  `struct(sha256 = "44e965bb067b2bb5cd9184dab2c3dea6e3eab747d341c07645bb4c88f09e49c8", url_templates = ["https://github.com/google/ksp/releases/download/{version}/artifacts.zip"], version = "2.1.21-2.0.1")` |
+| <a id="kotlin_repositories-kotlin_native_release_linux_x86_64"></a>kotlin_native_release_linux_x86_64 |  (internal) version provider from versions.bzl   |  `struct(sha256 = "42fb88529b4039b6ac1961a137ccb1c79fc80315947f3ec31b56834c7ce20d0b", strip_prefix_template = "kotlin-native-prebuilt-linux-x86_64-{version}", url_templates = ["https://github.com/JetBrains/kotlin/releases/download/v{version}/kotlin-native-prebuilt-linux-x86_64-{version}.tar.gz"], version = "2.1.21")` |
+| <a id="kotlin_repositories-kotlin_native_release_macos_x86_64"></a>kotlin_native_release_macos_x86_64 |  (internal) version provider from versions.bzl   |  `struct(sha256 = "fc6b5979ec322be803bfac549661aaf0f8f7342aa3bd09008d471fff2757bbdf", strip_prefix_template = "kotlin-native-prebuilt-macos-x86_64-{version}", url_templates = ["https://github.com/JetBrains/kotlin/releases/download/v{version}/kotlin-native-prebuilt-macos-x86_64-{version}.tar.gz"], version = "2.1.21")` |
+| <a id="kotlin_repositories-kotlin_native_release_macos_aarch64"></a>kotlin_native_release_macos_aarch64 |  <p align="center"> - </p>   |  `struct(sha256 = "8df16175b962bc4264a5c3b32cb042d91458babbd093c0f36194dc4645f5fe2e", strip_prefix_template = "kotlin-native-prebuilt-macos-aarch64-{version}", url_templates = ["https://github.com/JetBrains/kotlin/releases/download/v{version}/kotlin-native-prebuilt-macos-aarch64-{version}.tar.gz"], version = "2.1.21")` |
+| <a id="kotlin_repositories-kotlin_native_release_windows_x86_64"></a>kotlin_native_release_windows_x86_64 |  (internal) version provider from versions.bzl   |  `struct(sha256 = "03301473bb9e68dadfdd265857a2a5913a147e700e345d32db73e0a21a2ffbfa", strip_prefix_template = "kotlin-native-prebuilt-windows-x86_64-{version}", url_templates = ["https://github.com/JetBrains/kotlin/releases/download/v{version}/kotlin-native-prebuilt-windows-x86_64-{version}.zip"], version = "2.1.21")` |
 
 
 <a id="versions.use_repository"></a>

kotlin/compiler/BUILD

@@ -15,6 +15,7 @@ load("//src/main/starlark/release:packager.bzl", "release_archive")
 # limitations under the License.
 load(":compiler.bzl", "kt_configure_compiler")
 load(":ksp.bzl", "kt_configure_ksp")
+load(":native.bzl", "kt_configure_native_compiler")
 
 package(default_visibility = ["//visibility:public"])
 
@@ -24,6 +25,9 @@ kt_configure_compiler()
 # Configures the KSP plugins
 kt_configure_ksp()
 
+# Configure the native compiler (used only for runfiles in KotlinBuilder)
+kt_configure_native_compiler()
+
 release_archive(
     name = "pkg",
     srcs = glob(["*.bzl"]),

kotlin/compiler/BUILD.release.bazel

@@ -15,6 +15,7 @@
 load("@bazel_skylib//:bzl_library.bzl", "bzl_library")
 load(":compiler.bzl", "kt_configure_compiler")
 load(":ksp.bzl", "kt_configure_ksp")
+load(":native.bzl", "kt_configure_native_compiler")
 
 package(default_visibility = ["//visibility:public"])
 
@@ -24,6 +25,9 @@ kt_configure_compiler()
 # Configures the KSP plugins
 kt_configure_ksp()
 
+# Configure the native compiler (used only for runfiles in KotlinBuilder)
+kt_configure_native_compiler()
+
 bzl_library(
     name = "compiler",
     srcs = glob(["*.bzl"]),

kotlin/compiler/compiler.bzl

@@ -25,18 +25,18 @@ KOTLIN_STDLIBS = [
     "//kotlin/compiler:trove4j",
 ]
 
-def _import_artifacts(artifacts, rule_kind):
-    _import_labels(artifacts.plugin, rule_kind)
-    _import_labels(artifacts.runtime, rule_kind)
-    _import_labels(artifacts.compile, rule_kind, neverlink = 1)
+def _import_artifacts(artifacts, rule_kind, compiler_repo = _KT_COMPILER_REPO):
+    _import_labels(artifacts.plugin, rule_kind, compiler_repo)
+    _import_labels(artifacts.runtime, rule_kind, compiler_repo)
+    _import_labels(artifacts.compile, rule_kind, compiler_repo, neverlink = 1)
 
-def _import_labels(labels, rule_kind, **rule_args):
+def _import_labels(labels, rule_kind, compiler_repo, **rule_args):
     for (label, file) in labels.items():
         if not file.endswith(".jar"):
             native.filegroup(
                 name = label,
                 srcs = [
-                    "@%s//:%s" % (_KT_COMPILER_REPO, label),
+                    "@%s//:%s" % (compiler_repo, label),
                 ],
             )
             return
@@ -46,10 +46,10 @@ def _import_labels(labels, rule_kind, **rule_args):
         args = dict(rule_args.items())
         args["visibility"] = ["//visibility:public"]
         args["name"] = label
-        args["jars"] = ["@%s//:%s" % (_KT_COMPILER_REPO, label)]
+        args["jars"] = ["@%s//:%s" % (compiler_repo, label)]
         sources = label + "-sources"
         if sources in labels:
-            args["srcjar"] = "@%s//:%s" % (_KT_COMPILER_REPO, sources)
+            args["srcjar"] = "@%s//:%s" % (compiler_repo, sources)
         rule_kind(**args)
 
 def kt_configure_compiler():

kotlin/compiler/native.bzl

@@ -0,0 +1,17 @@
+load("//kotlin/internal:defs.bzl", "KT_NATIVE_COMPILER_REPO_PREFIX")
+
+def kt_configure_native_compiler():
+    # Ideally this would not be needed here and be available from the toolchain
+    # but the builder uses java_binary and jvm_flags are propagated for the runfile paths to it directly
+    # so it doesn't seem straightforward to do that, so this alias target allows us
+    # to reference it in the data dependencies there
+    native.alias(
+        name = "kotlin-native",
+        actual = select({
+            "@bazel_tools//src/conditions:linux_x86_64": "@" + KT_NATIVE_COMPILER_REPO_PREFIX + "_" + "linux_x86_64//:kotlin-native",
+            "@bazel_tools//src/conditions:darwin": "@" + KT_NATIVE_COMPILER_REPO_PREFIX + "_" + "macos_x86_64//:kotlin-native",
+            "@bazel_tools//src/conditions:windows": "@" + KT_NATIVE_COMPILER_REPO_PREFIX + "_" + "windows_x86_64//:kotlin-native",
+            "@bazel_tools//src/conditions:darwin_arm64": "@" + KT_NATIVE_COMPILER_REPO_PREFIX + "_" + "macos_aarch64//:kotlin-native",
+        }),
+        visibility = ["//src:__subpackages__"],
+    )

kotlin/internal/BUILD

@@ -30,6 +30,7 @@ release_archive(
     deps = [
         "//kotlin/internal/jvm:pkg",
         "//kotlin/internal/lint:pkg",
+        "//kotlin/internal/native:pkg",
         "//kotlin/internal/utils:pkg",
     ],
 )
@@ -41,6 +42,7 @@ bzl_library(
     deps = [
         "//kotlin/internal/jvm",
         "//kotlin/internal/lint",
+        "//kotlin/internal/native",
         "//kotlin/internal/utils",
         "//src/main/starlark",
         "//src/main/starlark/core/compile",

kotlin/internal/BUILD.release.bazel

@@ -24,6 +24,7 @@ bzl_library(
     deps = [
         "//kotlin/internal/jvm",
         "//kotlin/internal/lint",
+        "//kotlin/internal/native",
         "//kotlin/internal/utils",
         "//src/main/starlark",
     ],

kotlin/internal/defs.bzl

@@ -16,6 +16,7 @@ load(
     _JAVA_RUNTIME_TOOLCHAIN_TYPE = "JAVA_RUNTIME_TOOLCHAIN_TYPE",
     _JAVA_TOOLCHAIN_TYPE = "JAVA_TOOLCHAIN_TYPE",
     _KtJvmInfo = "KtJvmInfo",
+    _KtKlibInfo = "KtKlibInfo",
 )
 load(
     "//src/main/starlark/core/plugin:providers.bzl",
@@ -27,6 +28,7 @@ load(
 
 # The Kotlin Toolchain type.
 TOOLCHAIN_TYPE = "%s" % Label("//kotlin/internal:kt_toolchain_type")
+NATIVE_TOOLCHAIN_TYPE = "%s" % Label("//kotlin/internal/native:kt_native_toolchain_type")
 
 # Java toolchains
 JAVA_TOOLCHAIN_TYPE = _JAVA_TOOLCHAIN_TYPE
@@ -35,6 +37,9 @@ JAVA_RUNTIME_TOOLCHAIN_TYPE = _JAVA_RUNTIME_TOOLCHAIN_TYPE
 # The name of the Kotlin compiler workspace.
 KT_COMPILER_REPO = "com_github_jetbrains_kotlin"
 
+# The preifx of the Kotlin native compiler workspace name (will be suffixed with the platform)
+KT_NATIVE_COMPILER_REPO_PREFIX = "com_github_jetbrains_kotlin_native"
+
 # The name of the KSP compiler plugin workspace
 KSP_COMPILER_PLUGIN_REPO = "com_github_google_ksp"
 
@@ -47,3 +52,5 @@ KspPluginInfo = _KspPluginInfo
 KtCompilerPluginOption = _KtCompilerPluginOption
 
 KtPluginConfiguration = _KtPluginConfiguration
+
+KtKlibInfo = _KtKlibInfo

kotlin/internal/native/BUILD.bazel

@@ -0,0 +1,24 @@
+load("@bazel_skylib//:bzl_library.bzl", "bzl_library")
+load("//kotlin/internal/native:toolchains.bzl", "kt_configure_native_toolchains")
+load("//src/main/starlark/release:packager.bzl", "release_archive")
+
+kt_configure_native_toolchains()
+
+release_archive(
+    name = "pkg",
+    srcs = glob(["*.bzl"]),
+    src_map = {
+        "BUILD.release.bazel": "BUILD.bazel",
+    },
+)
+
+bzl_library(
+    name = "native",
+    srcs = glob(["*.bzl"]),
+    visibility = ["//kotlin:__subpackages__"],
+    deps = [
+        "//kotlin/internal/utils",
+        "//src/main/starlark/core/repositories/kotlin",
+        "@bazel_skylib//rules/directory",
+    ],
+)

kotlin/internal/native/BUILD.release.bazel

@@ -0,0 +1,15 @@
+load("@bazel_skylib//:bzl_library.bzl", "bzl_library")
+load(":toolchains.bzl", "kt_configure_native_toolchains")
+
+kt_configure_native_toolchains()
+
+bzl_library(
+    name = "native",
+    srcs = glob(["*.bzl"]),
+    visibility = ["//kotlin:__subpackages__"],
+    deps = [
+        "//kotlin/internal/utils",
+        "//src/main/starlark/core/repositories/kotlin",
+        "@bazel_skylib//rules/directory",
+    ],
+)

kotlin/internal/native/library.bzl

@@ -0,0 +1,91 @@
+load("//kotlin/internal:defs.bzl", _KtKlibInfo = "KtKlibInfo", _NATIVE_TOOLCHAIN_TYPE = "NATIVE_TOOLCHAIN_TYPE", _TOOLCHAIN_TYPE = "TOOLCHAIN_TYPE")
+load("//kotlin/internal/utils:utils.bzl", "utils")
+
+def _kt_library_impl(ctx):
+    module_name = utils.derive_module_name(ctx)
+    builder_args = utils.init_args(ctx, "kt_library", module_name)
+
+    klib = ctx.actions.declare_file("{}.klib".format(ctx.label.name))
+    outputs = [klib]
+
+    toolchains = ctx.toolchains[_TOOLCHAIN_TYPE]
+
+    # Retrieve konan.home from the chosen toolchain's distribution
+    native_toolchain_info = ctx.toolchains[_NATIVE_TOOLCHAIN_TYPE].kotlin_native_info
+    konan_home = native_toolchain_info.konan_home
+    native_target = native_toolchain_info.target
+
+    deps_klibs = []
+    transitive_klibs = []
+    runfiles = ctx.runfiles(files = [klib] + ctx.files.data)
+
+    for dep in ctx.attr.deps:
+        deps_klibs.append(dep[_KtKlibInfo].klibs)
+        transitive_klibs.append(dep[_KtKlibInfo].transitive_klibs)
+        runfiles = runfiles.merge(dep[DefaultInfo].default_runfiles)
+
+    for d in ctx.attr.data:
+        runfiles = runfiles.merge(d[DefaultInfo].default_runfiles)
+
+    libraries = depset(transitive = deps_klibs)
+    builder_args.add_all("--sources", ctx.files.srcs)
+    builder_inputs, _, input_manifests = ctx.resolve_command(tools = [toolchains.kotlinbuilder])
+
+    builder_args.add("--strict_kotlin_deps", "off")
+    builder_args.add("--reduced_classpath_mode", "off")
+    builder_args.add("--output_klib", klib.path)
+    builder_args.add("--kotlin_native_target", native_target)
+
+    libraries = depset(transitive = deps_klibs)
+    builder_args.add_all("--klibs", libraries)
+    builder_args.add("--konan_home", konan_home.path)
+
+    ctx.actions.run(
+        mnemonic = "KotlinKlibCompile",
+        inputs = depset(builder_inputs + ctx.files.srcs, transitive = [libraries, native_toolchain_info.konan_home_files]),
+        outputs = outputs,
+        executable = toolchains.kotlinbuilder.files_to_run.executable,
+        tools = [
+            toolchains.kotlinbuilder.files_to_run,
+        ],
+        execution_requirements = {"supports-workers": "1"},
+        arguments = [ctx.actions.args().add_all(toolchains.builder_args), builder_args],
+        progress_message = "Compiling Kotlin to Klib %%{label} { kt: %d }" % len(ctx.files.srcs),
+        input_manifests = input_manifests,
+        env = {
+            "REPOSITORY_NAME": utils.builder_workspace_name(ctx),
+        },
+    )
+
+    return [
+        DefaultInfo(files = depset(outputs, transitive = transitive_klibs + deps_klibs), runfiles = runfiles),
+        _KtKlibInfo(
+            klibs = depset(outputs),
+            transitive_klibs = depset(transitive = transitive_klibs + deps_klibs),
+        ),
+    ]
+
+kt_library = rule(
+    implementation = _kt_library_impl,
+    doc = """
+This rule is intended to leverage the new Kotlin IR backend to allow for compiling platform-independent Kotlin code
+to be shared between Kotlin code for different platforms (JS/JVM/WASM etc.). It produces a klib file as the output.
+    """,
+    attrs = {
+        "srcs": attr.label_list(
+            doc = "A list of source files to be compiled to klib",
+            allow_files = [".kt"],
+        ),
+        "deps": attr.label_list(
+            doc = "A list of other kt_klib_library targets that this library depends on for compilation",
+            providers = [_KtKlibInfo],
+        ),
+        "data": attr.label_list(
+            doc = """The list of files needed by this rule at runtime. See general comments about `data` at
+                [Attributes common to all build rules](https://docs.bazel.build/versions/master/be/common-definitions.html#common-attributes).""",
+            allow_files = True,
+        ),
+    },
+    toolchains = [_TOOLCHAIN_TYPE, _NATIVE_TOOLCHAIN_TYPE],
+    provides = [_KtKlibInfo],
+)