Add FASTQ_ALIGN_CONVERT_STAR_SAMTOOLS subworkflow

subworkflows/nf-core/fastq_align_convert_star_samtools/main.nf

@@ -0,0 +1,55 @@
+include { SAMTOOLS_CONVERT  } from '../../../modules/nf-core/samtools/convert/main'
+include { STAR_ALIGN        } from '../../../modules/nf-core/star/align/main'
+include { SAMTOOLS_INDEX    } from '../../../modules/nf-core/samtools/index/main.nf'
+
+workflow FASTQ_ALIGN_CONVERT_STAR_SAMTOOLS {
+    take:
+    reads           // channel: [ meta, [ fastq1, fastq2 ]]
+    index           // channel: [ meta, index ]
+    gtf             // channel: [ meta, gtf ]
+    fasta           // channel: [ meta, fasta ]
+    fai             // channel: [ meta, fai ]
+    ignore_sjdbgtf  // boolean
+    cram            // boolean: Create CRAM files
+
+    main:
+    def ch_versions = Channel.empty()
+    STAR_ALIGN(
+        reads,
+        index,
+        gtf,
+        ignore_sjdbgtf,
+        "", // seq_platform is handled in the config
+        ""  // seq_center is handled in the config
+    )
+    ch_versions = ch_versions.mix(STAR_ALIGN.out.versions.first())
+
+    SAMTOOLS_INDEX(
+        STAR_ALIGN.out.bam_sorted_aligned
+    )
+    ch_versions = ch_versions.mix(SAMTOOLS_INDEX.out.versions.first())
+
+    ch_bam_bai = STAR_ALIGN.out.bam_sorted_aligned
+        .join(SAMTOOLS_INDEX.out.bai, failOnMismatch:true, failOnDuplicate:true)
+
+    def ch_cram_crai = Channel.empty()
+    if(cram) {
+        SAMTOOLS_CONVERT(
+            STAR_ALIGN.out.bam_sorted_aligned.map { meta, bam -> [ meta, bam, []] },
+            fasta,
+            fai
+        )
+        ch_versions = ch_versions.mix(SAMTOOLS_CONVERT.out.versions.first())
+        ch_cram_crai = SAMTOOLS_CONVERT.out.cram
+            .join(SAMTOOLS_CONVERT.out.crai, failOnMismatch:true, failOnDuplicate:true)
+    }
+
+    emit:
+    versions      = ch_versions                      // channel: [ versions ]
+    bam_bai       = ch_bam_bai                       // channel: [ val(meta), path(bam), path(bai) ]
+    cram_crai     = ch_cram_crai                     // channel: [ val(meta), path(cram), path(crai) ]
+    junctions     = STAR_ALIGN.out.junction          // channel: [ val(meta), path(junction) ]
+    spl_junc_tabs = STAR_ALIGN.out.spl_junc_tab      // channel: [ val(meta), path(spl_jun_tab) ]
+    log_final     = STAR_ALIGN.out.log_final         // channel: [ val(meta), path(log_final) ]
+    gene_count    = STAR_ALIGN.out.read_per_gene_tab // channel: [ val(meta), path(read_per_gene_tab) ]
+}

subworkflows/nf-core/fastq_align_convert_star_samtools/meta.yml

@@ -0,0 +1,104 @@
+# yaml-language-server: $schema=https://raw.githubusercontent.com/nf-core/modules/master/subworkflows/yaml-schema.json
+name: "FASTQ_ALIGN_CONVERT_STAR_SAMTOOLS"
+description: "Align FASTQ reads using STAR, index BAM files with samtools, and optionally convert to CRAM format"
+keywords:
+  - alignment
+  - star
+  - samtools
+  - rna-seq
+  - bam
+  - cram
+  - indexing
+  - conversion
+components:
+  - samtools/convert
+  - star/align
+  - samtools/index
+input:
+  - reads:
+      type: file
+      description: |
+        Structure: [ val(meta), path(fastq) ]
+        One or two FASTQ files for single or paired end data respectively.
+      pattern: "*.{fq,fastq,fq.gz,fastq.gz}"
+  - index:
+      type: directory
+      description: |
+        Structure: [ val(meta), path(index) ]
+        STAR genome index directory
+      pattern: "star_index"
+  - gtf:
+      type: file
+      description: |
+        Structure: [ val(meta), path(gtf) ]
+        Reference GTF annotation file
+      pattern: "*.{gtf,gtf.gz}"
+  - fasta:
+      type: file
+      description: |
+        Structure: [ val(meta), path(fasta) ]
+        Reference genome FASTA file
+      pattern: "*.{fa,fasta,fa.gz,fasta.gz}"
+  - fai:
+      type: file
+      description: |
+        Structure: [ val(meta), path(fai) ]
+        Reference genome FASTA index file
+      pattern: "*.fai"
+  - ignore_sjdbgtf:
+      type: boolean
+      description: Indicates whether to ignore splice junctions from GTF file
+  - cram:
+      type: boolean
+      description: Indicates whether to convert BAM files to CRAM format
+output:
+  - versions:
+      type: file
+      description: |
+        Structure: [ path(versions.yml) ]
+        File containing software versions
+      pattern: "versions.yml"
+  - bam_bai:
+      type: file
+      description: |
+        Structure: [ val(meta), path("*.bam"), path ("*.bai") ]
+        Sorted BAM file and its index
+      pattern: "*.{bam,bai}"
+  - cram_crai:
+      type: file
+      description: |
+        Structure: [ val(meta), path("*.cram"), path("*.crai") ]
+        CRAM file and its index (optional, only when cram=true)
+      pattern: "*.{cram,crai}"
+  - junctions:
+      type: file
+      description: |
+        Structure: [ val(meta), path('*.out.junction') ]
+        STAR splice junction files
+      pattern: "*.SJ.out.tab"
+  - spl_junc_tabs:
+      type: file
+      description: |
+        Structure: [ tuple val(meta), path('*.SJ.out.tab') ]
+        STAR splice junction tab files
+      pattern: "*.tab"
+  - log_final:
+      type: file
+      description: |
+        Structure: [ val(meta), path('*Log.final.out') ]
+        STAR final log files
+      pattern: "*Log.final.out"
+  - gene_count:
+      type: file
+      description: |
+        Structure: [ val(meta), path('*.ReadsPerGene.out.tab') ]
+        STAR gene count files
+      pattern: "*ReadsPerGene.out.tab"
+authors:
+  - "@rannick"
+  - "@nvnieuwk"
+  - "@atrigila"
+maintainers:
+  - "@rannick"
+  - "@nvnieuwk"
+  - "@atrigila"